1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
|
%defines
%{
# include <string>
# include "builder.h"
# include "action.h"
# include "command.h"
# include "rule.h"
# include "filetarget.h"
# include "build.tab.h"
void yyerror( YYLTYPE *locp, Builder &bld, char const *msg );
%}
%parse-param { Builder &bld }
%lex-param { Builder &bld }
%pure-parser
%locations
%debug
%error-verbose
%union {
char *strval;
}
%token <strval> STRING "string literal"
%token <strval> REGEXP "regular expression"
%token TOK_ADDSET "+="
%token TOK_DEFAULT "default"
%token TOK_ACTION "action"
%token TOK_CREATE "create"
%token TOK_FILE "file"
%token TOK_FROM "from"
%token TOK_FILES "files"
%token TOK_IN "in"
%token TOK_USING "using"
%token TOK_RULE "rule"
%token TOK_REQUIRES "requires"
%token TOK_FOR "for"
%token TOK_SET "set"
%token TOK_MATCHES "matches"
%token TOK_MATCHING "matching"
%token TOK_ALL "all"
%token TOK_ONE "one"
%token TOK_PERFORM "perform"
%token TOK_PRODUCES "produces"
%token TOK_COMMAND "command"
%token TOK_CHECK "check"
%token TOK_CLEAN "clean"
%token TOK_DIRECTORIES "directories"
%token TOK_TARGETS "targets"
%token TOK_EOL "end of line"
%token ',' ':' '='
%destructor { delete[] $$; } STRING
%%
input:
| input fullline
;
fullline: TOK_EOL
| line TOK_EOL
;
line: TOK_DEFAULT TOK_ACTION ':'
{
bld.add( new Action() );
}
actionlst
| STRING TOK_ACTION ':'
{
bld.add( new Action( $1 ) );
}
actionlst
| TOK_FOR fortypes TOK_MATCHING REGEXP
{
bld.setFilter( $4 );
}
augments
{
bld.endList();
}
listcmds
| STRING TOK_REQUIRES
{
bld.setTmp( $1 );
bld.requiresRegexp( false );
}
reqcompletion
| REGEXP TOK_REQUIRES
{
bld.setTmp( $1 );
bld.requiresRegexp( true );
}
reqcompletion
| listcmds
| TOK_FOR STRING
{
bld.startList( STRING );
bld.addListItem( $2 );
}
listcmds
{
}
| rule
;
fortypes: TOK_DIRECTORIES
{
bld.startList( TOK_DIRECTORIES );
}
| TOK_TARGETS
{
bld.startList( TOK_TARGETS );
}
| TOK_FILES
{
bld.startList( TOK_FILES );
}
;
augments:
| TOK_IN STRING
{
bld.augmentList( $2 );
}
;
reqcompletion: reqlst
| TOK_FROM TOK_COMMAND STRING
{
bld.requiresFromCommand( bld.getTmp(), $3 );
}
;
reqlst: STRING
{
bld.requires( bld.getTmp(), $1 );
}
| reqlst ',' STRING
{
bld.requires( bld.getTmp(), $3 );
}
;
listcmds: TOK_SET setexpr
| TOK_CREATE createwhat TOK_FROM createfrom TOK_USING createusing
{
bld.endTarget();
}
;
createwhat: TOK_FILE STRING
{
bld.addTarget( TOK_FILE, $2 );
}
;
createfrom: TOK_FILES TOK_IN
{
bld.setTargetInputType( TOK_FILES );
}
createfromdirlst
;
createfromdirlst: createfromdir
| createfromdirlst ',' createfromdir
;
createfromdir: STRING
{
bld.addTargetInput( $1 );
}
;
createusing: TOK_RULE STRING
{
bld.setTargetRule( $2 );
}
;
actionlst: action
| actionlst ',' action
;
action: TOK_CHECK STRING
{
bld.add( new Command( Command::cmdCheck, $2 ) );
}
| TOK_CHECK REGEXP
{
bld.addRegexCommand( Command::cmdCheck, $2 );
}
| TOK_CLEAN STRING
{
bld.add( new Command( Command::cmdClean, $2 ) );
}
| TOK_CLEAN REGEXP
{
bld.addRegexCommand( Command::cmdClean, $2 );
}
;
setexpr: STRING '=' STRING
{
bld.varSet( $1, $3 );
}
| STRING TOK_ADDSET STRING
{
bld.varAddSet( $1, $3 );
}
;
rule: TOK_RULE STRING
{
bld.add( new Rule( $2 ) );
}
rulesublst TOK_PERFORM rulecompletion
;
rulesublst: rulesub
| rulesublst rulesub
;
rulesub: TOK_MATCHES rulematches
| TOK_PRODUCES produceslst
;
produceslst: STRING
{
bld.lastRule()->addProduces( $1 );
}
| produceslst ',' STRING
{
bld.lastRule()->addProduces( $3 );
}
;
rulematches: TOK_ALL REGEXP
{
try
{
bld.lastRule()->setMatches( Rule::matchAll, $2 );
}
catch( BuildException &e )
{
std::string s("RegExp compile error: ");
s += e.what();
yyerror( &yyloc, bld, s.c_str() );
return 1;
}
}
| TOK_ONE REGEXP
{
try
{
bld.lastRule()->setMatches( Rule::matchOne, $2 );
}
catch( BuildException &e )
{
std::string s("RegExp compile error: ");
s += e.what();
yyerror( &yyloc, bld, s.c_str() );
return 1;
}
}
;
rulecompletion: TOK_COMMAND STRING
{
bld.lastRule()->setPerforms( Rule::perfCommand, $2 );
}
;
%%
void yyerror( YYLTYPE *locp, Builder &bld, char const *msg )
{
bld.error( locp, msg );
}
|
